رباتیک و هوافضا

مانیتورینگ ضربان قلب بر روی اینترنت بوسیله Arduino و ThingSpeak

مانیتورینگ ضربان قلب بر روی اینترنت بوسیله Arduino و ThingSpeak

به نام خدا

مانیتورینگ ضربان قلب بر روی اینترنت بوسیله Arduino و ThingSpeak

مانیتورینگ ضربان قلب بر روی اینترنت بوسیله Arduino و ThingSpeak

در این پروژه قصد داریم یک ضربان قلب سنج و سیستم مانیتورینگ ان را بوسیله آردینو بسازیم. این سیستم بعد از تشخیص ضربان قلب بوسیله سنسور پالس، ضربان  قلب را برحسب BPM (ضربان در دقیقه) روی LCD نمایش می دهد. همچنین این اطلاعات را بوسیله ماژول وای فای ESP8266 به سرور ThingSpeak ارسال می کند تا بتوان این ضربان قلب را در هر جای دنیا بر روی اینترنت مشاهده کرد. ThingSpeak یک منبع عالی برای نمایش داده ها به صورت آنلاین میباشد که میتوان در هر زمان و مکانی به وسیله ان به این داده ها دسترسی پیدا کرد.

ما قبلا مانیتور ضربان قلب ساده را بدون نمایش ان روی اینترنت ساخته ایم. اینبار از ThingSpeak برای مانیتور کردن ضربان قلب استفاده میکنیم با این کار پروژه ما در دسته اینترنت اشیاء قرار میگیرد.

 

قطعات مورد نیاز پروژه ی مانیتورینگ ضربان قلب بر روی اینترنت بوسیله Arduino و ThingSpeak :

  • سنسور پالس
  • ماژول وای فای ESP8266
  • Arduino UNO
  • LCD
  • برد بورد
  • مقاومت متغییر ۱۰ کیلو اهمی
  • مقاومت  ۱ کیلو اهمی
  • مقاومت  ۲۲۰ اهمی
  • LED
  • سیم برد بورد

توضیح و دیاگرام مدار:

اول از همه ماژول وای فای ESP8266 را به آردینو متصل میکنیم. ولتاژ تغذیه این ماژول ۳٫۳ میباشد واگر ولتاژ ۵ ولت به ان اعمال شود احتمال دارد خراب شود. VCC و CH_PD را به پایه تغذیه ۳٫۳ آردینو متصل کنید. پایه RX ماژول ESP8266 با ولتاژ ۳٫۳ کار میکند، اگر این  پایه را به صورت مستقیم به آردینو متصل کنیم ارتباطی بین ESP8266 و آردینو برقرار نمیشود. بنابراین باید ۵ ولت را با قرار دادن مقاومت به صورت سری بین این دو پایه تقسیم کنیم تا به ولتاژ ۳٫۳ برسیم. پایه TX ماژول به پایه ۹ آردینو و پایه RX همراه با مقاومت سری به پایه ۱۰ آردینو متصل می شود.

مانیتورینگ ضربان قلب بر روی اینترنت بوسیله Arduino و ThingSpeak

 

اتصال سنسور پالس بسیار ساده است. این سنسور ها سه پایه دارند. پایه ۵ ولت و زمین این سنسور را به ۵ ولت و زمین آردینو و پایه سیگنال سنسور را به پایه A0 آردینو متصل میکنیم.

مانیتورینگ ضربان قلب بر روی اینترنت بوسیله Arduino و ThingSpeak

سپس LED را به پایه ۱۳ آردینو متصل میکنیم.نیازی به استفاده از مقاومت برای LED نیست.

در اخر باید LCD را به صورت زیر به آردینو متصل کنیم.

  • (PIN1( VEE به زمین
  • (PIN 2 (VDD /VCC به ۵ ولت
  • (PIN 3 (V0 به پایه وسط مقاومت متغییر و دو پایه دیگر مقاومت متغییر به VCC و GND. وظیفه مقاومت متغییر کنترل روشنایی صفحه LCD است
  • (PIN4 (RS به پایه ۱۲ اردینو
  • (PIN5 (READ/WRITE به زمین
  • (PIN6 (E به پایه ۱۱ اردینو
  • چهار پایه بعدی که برای ارتباط با آردینو است به صورت زیر می باشد:

(PIN11 (D4 به پایه ۵

(PIN12 (D5 به پایه ۴

(PIN13 (D6 به پایه ۳

(PIN14 (D7 به پایه ۲

  • (PIN (15 به سیله مقامومت ۲۲۰ اهم به VCC
  • (PIN (16 به زمین

مانیتورینگ ضربان قلب بر روی اینترنت بوسیله Arduino و ThingSpeak

تنظیمات ThingSpeak:

ThingSpeak ابزار بسیار مناسبی برای پروژه های مبتی بر اینترنت اشیاء می باشد. به وسیله سایت ThingSpeak، می توانیم با استفاده از اینترنت داده هایمان را مانیتور و سیستم مان را کنترل کنیم. ThingSpeak اطلاعات را از سنسور ها جمع آوری و تجزیه وتحلیل می کند و با این اطلاعات عملیاتی که ما می خواهیم را انجام می دهد.در اینجا به طور خلاصه توضیح میدهیم که چگونه با ThingSpeak پروژه مان را راه اندازی کنیم.

در ابتدا نیاز داریم تا یک پروفایل در این سایت بسازیم، پس وارد سایت میشویم و روی Get Started کلیک میکنیم.

بیشتر بخوانید...  تشخیص و شناخت دست خط با استفاده از شبکه عصبی

مانیتورینگ ضربان قلب بر روی اینترنت بوسیله Arduino و ThingSpeak

بعد از ساخت پروفایل به قسمت channels رفته و گزینه create a new channel را انتخاب کنید.سپس اسم کانال را درقسمت name وارد می کنیم.همچنین گزینه Make Public را در زیر فرم فعال کنید و درنهایت کانال را ذخیره کنید.

مانیتورینگ ضربان قلب بر روی اینترنت بوسیله Arduino و ThingSpeak

حال به قسمت APIKEYS رفته و Write API Key را کپی کنید.این قسمت را در برنامه ای که روی آردینو میریزید نیاز دارید.مانیتورینگ ضربان قلب بر روی اینترنت بوسیله Arduino و ThingSpeak

طرز کار :

ماژول وای فای ESP8266 با آردینو در ارتباط است و آردینو اطلاعات مربوطه را به وسیله این ماژول و وصل شدن به کانالی که در سایت ThingSpeak ساخته ایم به سرور ThingSpeak می فرستد. اطلاعات ارسال شده در نموداری به نمایش گذاشته می شود و میتوان از هرجای دنیا بوسیله اینترنت این اطلاعات را مشاهده کرد. LCD موجود هم میتواند ضربان را به نمایش بگذارد.

مانیتورینگ ضربان قلب بر روی اینترنت بوسیله Arduino و ThingSpeak

مانیتورینگ ضربان قلب بر روی اینترنت بوسیله Arduino و ThingSpeak

دانلود کد های پروژه مانیتورینگ ضربان قلب بر روی اینترنت بوسیله Arduino و ThingSpeak :

دانلود فایل

 

#include <SoftwareSerial.h>
#define DEBUG true
SoftwareSerial esp8266(9,10); 
#include <LiquidCrystal.h>
#include <stdlib.h>
LiquidCrystal lcd(12,11,5,4,3,2);

#define SSID "Your Wifi Name"     // "SSID-WiFiname" 
#define PASS "Your Wifi Password"       // "password"
#define IP "184.106.153.149"// thingspeak.com ip
String msg = "GET /update?key=9YS21NU0HY5YS1IKU"; //change it with your api key like "GET /update?key=Your Api Key"

//Variables
float temp;
int hum;
String tempC;
int error;
int pulsePin = 0;                 // Pulse Sensor purple wire connected to analog pin 0
int blinkPin = 13;                // pin to blink led at each beat
int fadePin = 5;
int fadeRate = 0;

// Volatile Variables, used in the interrupt service routine!
volatile int BPM;                   // int that holds raw Analog in 0. updated every 2mS
volatile int Signal;                // holds the incoming raw data
volatile int IBI = 600;             // int that holds the time interval between beats! Must be seeded! 
volatile boolean Pulse = false;     // "True" when heartbeat is detected. "False" when not a "live beat". 
volatile boolean QS = false;        // becomes true when Arduino finds a beat.

// Regards Serial OutPut  -- Set This Up to your needs
static boolean serialVisual = true;   // Set to 'false' by Default.  Re-set to 'true' to see Arduino Serial Monitor ASCII Visual Pulse 
volatile int rate[10];                    // array to hold last ten IBI values
volatile unsigned long sampleCounter = 0;          // used to determine pulse timing
volatile unsigned long lastBeatTime = 0;           // used to find IBI
volatile int P =512;                      // used to find peak in pulse wave, seeded
volatile int T = 512;                     // used to find trough in pulse wave, seeded
volatile int thresh = 525;                // used to find instant moment of heart beat, seeded
volatile int amp = 100;                   // used to hold amplitude of pulse waveform, seeded
volatile boolean firstBeat = true;        // used to seed rate array so we startup with reasonable BPM
volatile boolean secondBeat = false;      // used to seed rate array so we startup with reasonable BPM

void setup()
{
  lcd.begin(16, 2);
  lcd.print("circuitdigest.com");
  delay(100);
  lcd.setCursor(0,1);
  lcd.print("Connecting...");
  Serial.begin(9600); //or use default 115200.
  esp8266.begin(9600);
  Serial.println("AT");
  esp8266.println("AT");
  delay(5000);
  if(esp8266.find("OK")){
    connectWiFi();
  }
  interruptSetup(); 
}

void loop(){
  lcd.clear();
  start: //label 
  error=0;
  lcd.setCursor(0, 0);
  lcd.print("BPM = ");
  lcd.print(BPM);
  delay (100);
  lcd.setCursor(0, 1); // set the cursor to column 0, line 2
  delay(1000);
  updatebeat();
  //Resend if transmission is not completed 
  if (error==1){
    goto start; //go to label "start"
  }
  
  delay(1000); 
}

void updatebeat(){
  String cmd = "AT+CIPSTART=\"TCP\",\"";
  cmd += IP;
  cmd += "\",80";
  Serial.println(cmd);
  esp8266.println(cmd);
  delay(2000);
  if(esp8266.find("Error")){
    return;
  }
  cmd = msg ;
  cmd += "&field1=";   
  cmd += BPM;
  cmd += "\r\n";
  Serial.print("AT+CIPSEND=");
  esp8266.print("AT+CIPSEND=");
  Serial.println(cmd.length());
  esp8266.println(cmd.length());
  if(esp8266.find(">")){
    Serial.print(cmd);
    esp8266.print(cmd);
  }
  else{
   Serial.println("AT+CIPCLOSE");
   esp8266.println("AT+CIPCLOSE");
    //Resend...
    error=1;
  }
}

boolean connectWiFi(){
  Serial.println("AT+CWMODE=1");
  esp8266.println("AT+CWMODE=1");
  delay(2000);
  String cmd="AT+CWJAP=\"";
  cmd+=SSID;
  cmd+="\",\"";
  cmd+=PASS;
  cmd+="\"";
  Serial.println(cmd);
  esp8266.println(cmd);
  delay(5000);
  if(esp8266.find("OK")){
    Serial.println("OK");
    return true;    
  }else{
    return false;
  }
}

void interruptSetup(){     
  TCCR2A = 0x02;     // DISABLE PWM ON DIGITAL PINS 3 AND 11, AND GO INTO CTC MODE
  TCCR2B = 0x06;     // DON'T FORCE COMPARE, 256 PRESCALER 
  OCR2A = 0X7C;      // SET THE TOP OF THE COUNT TO 124 FOR 500Hz SAMPLE RATE
  TIMSK2 = 0x02;     // ENABLE INTERRUPT ON MATCH BETWEEN TIMER2 AND OCR2A
  sei();             // MAKE SURE GLOBAL INTERRUPTS ARE ENABLED      
} 

ISR(TIMER2_COMPA_vect){                       // triggered when Timer2 counts to 124
  cli();                                      // disable interrupts while we do this
  Signal = analogRead(pulsePin);              // read the Pulse Sensor 
  sampleCounter += 2;                         // keep track of the time in mS
  int N = sampleCounter - lastBeatTime;       // monitor the time since the last beat to avoid noise

    //  find the peak and trough of the pulse wave
  if(Signal < thresh && N > (IBI/5)*3){      // avoid dichrotic noise by waiting 3/5 of last IBI
    if (Signal < T){                         // T is the trough
      T = Signal;                            // keep track of lowest point in pulse wave 
    }
  }

  if(Signal > thresh && Signal > P){        // thresh condition helps avoid noise
    P = Signal;                             // P is the peak
  }                                         // keep track of highest point in pulse wave

  //  NOW IT'S TIME TO LOOK FOR THE HEART BEAT
  // signal surges up in value every time there is a pulse
  if (N > 250){                                   // avoid high frequency noise
    if ( (Signal > thresh) && (Pulse == false) && (N > (IBI/5)*3) ){        
      Pulse = true;                               // set the Pulse flag when there is a pulse
      digitalWrite(blinkPin,HIGH);                // turn on pin 13 LED
      IBI = sampleCounter - lastBeatTime;         // time between beats in mS
      lastBeatTime = sampleCounter;               // keep track of time for next pulse

      if(secondBeat){                        // if this is the second beat
        secondBeat = false;                  // clear secondBeat flag
        for(int i=0; i<=9; i++){             // seed the running total to get a realistic BPM at startup
          rate[i] = IBI;                      
        }
      }

      if(firstBeat){                         // if it's the first time beat is found
        firstBeat = false;                   // clear firstBeat flag
        secondBeat = true;                   // set the second beat flag
        sei();                               // enable interrupts again
        return;                              // IBI value is unreliable so discard it
      }   
      word runningTotal = 0;                  // clear the runningTotal variable    

      for(int i=0; i<=8; i++){                // shift data in the rate array
        rate[i] = rate[i+1];                  // and drop the oldest IBI value 
        runningTotal += rate[i];              // add up the 9 oldest IBI values
      }

      rate[9] = IBI;                          // add the latest IBI to the rate array
      runningTotal += rate[9];                // add the latest IBI to runningTotal
      runningTotal /= 10;                     // average the last 10 IBI values 
      BPM = 60000/runningTotal;               // how many beats can fit into a minute? that's BPM!
      QS = true;                              // set Quantified Self flag 
      // QS FLAG IS NOT CLEARED INSIDE THIS ISR
    }                       
  }

  if (Signal < thresh && Pulse == true){   // when the values are going down, the beat is over
    digitalWrite(blinkPin,LOW);            // turn off pin 13 LED
    Pulse = false;                         // reset the Pulse flag so we can do it again
    amp = P - T;                           // get amplitude of the pulse wave
    thresh = amp/2 + T;                    // set thresh at 50% of the amplitude
    P = thresh;                            // reset these for next time
    T = thresh;
  }

  if (N > 2500){                           // if 2.5 seconds go by without a beat
    thresh = 512;                          // set thresh default
    P = 512;                               // set P default
    T = 512;                               // set T default
    lastBeatTime = sampleCounter;          // bring the lastBeatTime up to date        
    firstBeat = true;                      // set these to avoid noise
    secondBeat = false;                    // when we get the heartbeat back
  }

  sei();     
  // enable interrupts when youre done!
}// end isr

 

بیشتر بخوانید...  آموزش پروژه محور آردوینو – جلسه سیزدهم موتور DC

 

دیدگاه‌ها (0)

*
*