رباتیک و هوافضا

ساخت ساعت دقیق با سیستم هشدار دهنده و نمایش دما با آردوینو و DS3231

ساخت ساعت دقیق به همراه آلارم و نمایشگر دما با آردوینو و ماژولDS3231

به نام خدا

ساخت ساعت دقیق با سیستم هشدار دهنده و نمایش دما با آردوینو و DS3231

 

ساخت-ساعت دقیق-بهمراه-آلارم-و نمایشگر-دما با-آردوینو-و-ماژول-DS3231

 

در این آموزش قصد داریم ساعت دقیقی بهمراه دو آلارم و نمایشگر دما بوسیله ماژول DS3231 و آردینو بسازیم. DS3231 ماژول ساعت زمان واقعی است(RTC)  که قابل برنامه ریزی ۲ زمان مختلف برای تنظیم آلارم و دماسنج است. دماسنج این ماژول با وضوح ۰٫۲۵ و دقت ۳ ± درجه است.

 

ساخت ساعت دقیق با سیستم هشدار دهنده و نمایش دما با آردوینو و DS3231:

  • برد آردینو
  • ماژول DS3231
  • lcd 20*4
  • ۳ عدد میکروسوئیچ
  • LED
  • پتانسیومتر ۱۰ کیلو اهم
  • ۲ عدد مقاومت ۳۳۰ اهم
  • باطری سکه ای ۳ ولت
  • برد بورد
  • سیم برد بورد

شماتیک مدار:

شماتیک مدار مانند شکل زیر است.

ساخت-ساعت دقیق-بهمراه-آلارم-و نمایشگر-دما با-آردوینو-و-ماژول-DS3231

 

ماژول DS3231 دارای چیپ DS3231 ، دو مقاومت پول آپ (۴٫۷K) در پایه های SCL, SDA ، پایهINT/SQW (وقفه آلارم) و جا باتری سکه ای می باشد. همچنین شامل ۲۴C32 EEPROM و مقاومت های دیگری می باشد که در این پروژه کاربردی ندارد.

ماژول DS3231 و led 20*4 هر دو با ۵ ولت و از آردینو تغذیه می شوند. سه پایه SCL , SDA و INT/SQW پایه های دیتا هستند و به ترتیب به پین آنالوگ ۴ و ۵ و پین دیجیتال ۲ که پین وقفه خارجی آردوینو می باشد متصل می شود. هنگامی که آلارم اتفاق می افتد یک وقفه توسط ماژول DS3231 به آردینو فرستاده می شود. در این مدار از سه میکروسوئیچ برای تنظیم ساعت ، زمان و آلارم استفاده شده.میکروسوئچ B1 برای انتخاب بین زمان و تقویم است (زمان شامل:ساعت و دقیقه و تقویم شامل: روز ، ماه و سال می باشد.) و B3 برای انتخاب پارامترهای آلارم(ساعت ، دقیقه و روشن یا خاموش بودن) و B2 برای افزایش این مقادیر است.

علاوه بر این LED متصل به پین ۱۲ آردینو برای نمایش اتفاق افتادن آلارم است. هر وقت آلارم صورت گیرد پایه وقفه (INT) فعال شده و LED روشن می شود در این زمان با میکروسوئیچ B2 می توان چراغ و آلارم را خاموش کرد.

کدهای آردوینو:

در این پروژه از کتابخانه ای برای ماژول DS3231 استفاده نمی کنیم. برنامه نویسی با استفاده از دیتا شیت ماژول ساده تر است.

این ماژول فقط از فرمت BCD (باینری) پشتیبانی می کند به همین منظور مجبور به تبدیل این مبنا به ده دهی هستیم. کد های این تبدیل و برعکس آن را در زیر می بینید.

   minute = (minute >> 4) * 10 + (minute & 0x0F);                                  // Convert BCD to decimal
minute = ((minute / 10) << 4) + (minute % 10);                                     // Convert decimal to BCD

توابع برنامه:

() void DS3231_read :

این تابع زمان وتقویم را از ماژول DS3231 می خواند.(ثانیه،دقیقه،ساعت،روز،ماه و سال)

() void DS3231_display :

این تابع زمان وتقویم را که به صورت ده دهی است روی LCD نشان می دهد. این تابع برای نمایش دادن تقویم تابع () void calendar_display را فراخوانی می کند.

()void alarms_read_display:

این تابع ساعت و دقیقه آلارم را می خواند علاوه بر این ریجستر کنترل ، وضعیت و دما را از ماژول می خواند.

کار دیگر این تابع نشان دادن اطلاعات آلارم (دقیقه ، ساعت و روشن یا خاموش بودن) و دما است. اطلاعات روشن یا خاموش بودن از ریجستر کنترل خوانده می شود.

(byte edit(byte x, byte y, byte parameter :

این تابع برای تنظیم زمان ، تقویم و آلارم است البته با این تابع نمی توان روز را تنظیم کرد. متغییری به نام i برای مشخص کردن این که کدام پارامتر در حال تغییر است تعریف شده است.

i = 0 , 1 : به ترتیب از راست به چپ برای دقیقه وساعت

۴, i = 2 , 3 : به ترتیب از راست به چپ برای سال ، ماه و روز

i = 5 , 6 : به ترتیب از راست به چپ برای دقیقه وساعت آلارم

i = 7 : برای خاموش یا روشن بودن آلارم

توضیحات:

آردوینو وقتی led را روشن می کند که توسط ماژول DS3231 وقفه اتفاق بیفتد و سیگنال وقفه ماژول DS3231 تنها وقتی آلارم اتفاق بیفتد به آردوینو فرستاده می شود. میکروسوئیچ B2 آلارم را ریست یا غیر فعال میکند. اگر هر دو آلارم فعال باشند میکروسوئیچ B2 فقط آلارمی را غیر فعال میکند که هم اکنون فعال شده و دیگری به حالت قبلی اش می ماند. برای اینکه متوجه شویم کدام آلارم هم اکنون رخ داده است باید به مقادیر ریجستر وضعیت ماژول DS3231 سرکشی کنیم (بیت های A1IF  و A2IF). خاموش و روشن کردن آلارم ها هم با استفاده از ریجستر کنترل ماژول صورت می گیرد(بیت های INTCN, A1IE و A2IE). بیت INTCN همیشه باید ۱ باشد. برای خاموش کردن آلارم  و ۱ کردن بیت INTCN از کد زیر استفاده می شود.

;((Wire.write(4 |(!bit_test(status_reg, 0)& alarm1_status)|((!bit_test(status_reg, 1) & alarm2_status) << 1

alarm2_status و alarm1_status بولین هستند (۰ یا ۱). اگر هر کدام از این مقادیر ۱ شوند آلارم مربوط به آنها روشن و در صورت ۰  شدن شان آلارم خاموش است.

دانلود کد های پروژه ساخت ساعت دقیق با سیستم هشدار دهنده و نمایش دما با آردوینو و DS3231:

دانلود فایل
 
// include LCD library code
#include <LiquidCrystal.h>
// include Wire library code (needed for I2C protocol devices)
#include <Wire.h>
 
// LCD module connections (RS, E, D4, D5, D6, D7)
LiquidCrystal lcd(3, 4, 5, 6, 7, 8);
 
const int button1   =  9;                   // button1 pin number
const int button2   = 10;                   // button1 pin number
const int button3   = 11;                   // button1 pin number
const int alarm_pin = 12;                   // Alarms pin number
 
void setup() {
  pinMode(9,  INPUT_PULLUP);
  pinMode(10, INPUT_PULLUP);
  pinMode(11, INPUT_PULLUP);
  pinMode(12, OUTPUT);
  digitalWrite(alarm_pin, LOW);
  // set up the LCD's number of columns and rows
  lcd.begin(20, 4);
  Wire.begin();                                 // Join i2c bus
  attachInterrupt(digitalPinToInterrupt(2), Alarm, FALLING);
}
 
// Variables declaration
bool alarm1_status, alarm2_status;
char Time[]     = "  :  :  ",
     calendar[] = "      /  /20  ",
     alarm1[]   = "A1:   :  :00", alarm2[]   = "A2:   :  :00",
     temperature[] = "T:   .   C";
byte  i, second, minute, hour, day, date, month, year,
      alarm1_minute, alarm1_hour, alarm2_minute, alarm2_hour,
      status_reg;
 
void Alarm(){
  digitalWrite(alarm_pin, HIGH);
}
void DS3231_read(){                             // Function to read time & calendar data
  Wire.beginTransmission(0x68);                 // Start I2C protocol with DS3231 address
  Wire.write(0);                                // Send register address
  Wire.endTransmission(false);                  // I2C restart
  Wire.requestFrom(0x68, 7);                    // Request 7 bytes from DS3231 and release I2C bus at end of reading
  second = Wire.read();                         // Read seconds from register 0
  minute = Wire.read();                         // Read minuts from register 1
  hour   = Wire.read();                         // Read hour from register 2
  day    = Wire.read();                         // Read day from register 3
  date   = Wire.read();                         // Read date from register 4
  month  = Wire.read();                         // Read month from register 5
  year   = Wire.read();                         // Read year from register 6
}
void alarms_read_display(){                     // Function to read and display alarm1, alarm2 and temperature data
  byte control_reg, temperature_lsb;
  char temperature_msb;
  Wire.beginTransmission(0x68);                 // Start I2C protocol with DS3231 address
  Wire.write(0x08);                             // Send register address
  Wire.endTransmission(false);                  // I2C restart
  Wire.requestFrom(0x68, 11);                   // Request 11 bytes from DS3231 and release I2C bus at end of reading
  alarm1_minute = Wire.read();                  // Read alarm1 minutes
  alarm1_hour   = Wire.read();                  // Read alarm1 hours
  Wire.read();                                  // Skip alarm1 day/date register
  alarm2_minute = Wire.read();                  // Read alarm2 minutes
  alarm2_hour   = Wire.read();                  // Read alarm2 hours
  Wire.read();                                  // Skip alarm2 day/date register
  control_reg = Wire.read();                    // Read the DS3231 control register
  status_reg  = Wire.read();                    // Read the DS3231 status register
  Wire.read();                                  // Skip aging offset register
  temperature_msb = Wire.read();                // Read temperature MSB
  temperature_lsb = Wire.read();                // Read temperature LSB
    // Convert BCD to decimal
  alarm1_minute = (alarm1_minute >> 4) * 10 + (alarm1_minute & 0x0F);
  alarm1_hour   = (alarm1_hour   >> 4) * 10 + (alarm1_hour & 0x0F);
  alarm2_minute = (alarm2_minute >> 4) * 10 + (alarm2_minute & 0x0F);
  alarm2_hour   = (alarm2_hour   >> 4) * 10 + (alarm2_hour & 0x0F);
    // End conversion
  alarm1[8]     = alarm1_minute % 10  + 48;
  alarm1[7]     = alarm1_minute / 10  + 48;
  alarm1[5]     = alarm1_hour   % 10  + 48;
  alarm1[4]     = alarm1_hour   / 10  + 48;
  alarm2[8]     = alarm2_minute % 10  + 48;
  alarm2[7]     = alarm2_minute / 10  + 48;
  alarm2[5]     = alarm2_hour   % 10  + 48;
  alarm2[4]     = alarm2_hour   / 10  + 48;
  alarm1_status = bitRead(control_reg, 0);      // Read alarm1 interrupt enable bit (A1IE) from DS3231 control register
  alarm2_status = bitRead(control_reg, 1);      // Read alarm2 interrupt enable bit (A2IE) from DS3231 control register
  if(temperature_msb < 0){
    temperature_msb = abs(temperature_msb);
    temperature[2] = '-';
  }
  else
    temperature[2] = ' ';
  temperature_lsb >>= 6;
  temperature[4] = temperature_msb % 10  + 48;
  temperature[3] = temperature_msb / 10  + 48;
  if(temperature_lsb == 0 || temperature_lsb == 2){
    temperature[7] = '0';
    if(temperature_lsb == 0) temperature[6] = '0';
    else                     temperature[6] = '5';
  }
  if(temperature_lsb == 1 || temperature_lsb == 3){
    temperature[7] = '5';
    if(temperature_lsb == 1) temperature[6] = '2';
    else                     temperature[6] = '7';
  }
  temperature[8]  = 223;                        // Put the degree symbol
  lcd.setCursor(10, 0);
  lcd.print(temperature);                       // Display temperature
  lcd.setCursor(0, 2);
  lcd.print(alarm1);                            // Display alarm1
  lcd.setCursor(17, 2);
  if(alarm1_status)  lcd.print("ON ");          // If A1IE = 1 print 'ON'
  else               lcd.print("OFF");          // If A1IE = 0 print 'OFF'
  lcd.setCursor(0, 3);
  lcd.print(alarm2);                            // Display alarm2
  lcd.setCursor(17, 3);
  if(alarm2_status)  lcd.print("ON ");          // If A2IE = 1 print 'ON'
  else               lcd.print("OFF");          // If A2IE = 0 print 'OFF'
}
void calendar_display(){                        // Function to display calendar
  switch(day){
    case 1:  strcpy(calendar, "Sun   /  /20  "); break;
    case 2:  strcpy(calendar, "Mon   /  /20  "); break;
    case 3:  strcpy(calendar, "Tue   /  /20  "); break;
    case 4:  strcpy(calendar, "Wed   /  /20  "); break;
    case 5:  strcpy(calendar, "Thu   /  /20  "); break;
    case 6:  strcpy(calendar, "Fri   /  /20  "); break;
    case 7:  strcpy(calendar, "Sat   /  /20  "); break;
    default: strcpy(calendar, "Sat   /  /20  ");
  }
  calendar[13] = year  % 10 + 48;
  calendar[12] = year  / 10 + 48;
  calendar[8]  = month % 10 + 48;
  calendar[7]  = month / 10 + 48;
  calendar[5]  = date  % 10 + 48;
  calendar[4]  = date  / 10 + 48;
  lcd.setCursor(0, 1);
  lcd.print(calendar);                          // Display calendar
}
void DS3231_display(){
  // Convert BCD to decimal
  second = (second >> 4) * 10 + (second & 0x0F);
  minute = (minute >> 4) * 10 + (minute & 0x0F);
  hour = (hour >> 4) * 10 + (hour & 0x0F);
  date = (date >> 4) * 10 + (date & 0x0F);
  month = (month >> 4) * 10 + (month & 0x0F);
  year = (year >> 4) * 10 + (year & 0x0F);
  // End conversion
  Time[7]     = second % 10  + 48;
  Time[6]     = second / 10  + 48;
  Time[4]     = minute % 10  + 48;
  Time[3]     = minute / 10  + 48;
  Time[1]     = hour   % 10  + 48;
  Time[0]     = hour   / 10  + 48;
  calendar_display();                           // Call calendar display function
  lcd.setCursor(0, 0);
  lcd.print(Time);                              // Display time
}
void Blink(){
  byte j = 0;
  while(j < 10 && (digitalRead(button1) || i >= 5) && digitalRead(button2) && (digitalRead(button3) || i < 5)){
    j++;
    delay(25);
  }
}
byte edit(byte x, byte y, byte parameter){
  char text[3];
  while(!digitalRead(button1) || !digitalRead(button3));    // Wait until button B1 is released
  while(true){
    while(!digitalRead(button2)){                           // If button B2 is pressed
      parameter++;
      if(((i == 0) || (i == 5)) && parameter > 23)          // If hours > 23 ==> hours = 0
        parameter = 0;
      if(((i == 1) || (i == 6)) && parameter > 59)          // If minutes > 59 ==> minutes = 0
        parameter = 0;
      if(i == 2 && parameter > 31)                          // If date > 31 ==> date = 1
        parameter = 1;
      if(i == 3 && parameter > 12)                          // If month > 12 ==> month = 1
        parameter = 1;
      if(i == 4 && parameter > 99)                          // If year > 99 ==> year = 0
        parameter = 0;
      if(i == 7 && parameter > 1)                           // For alarms ON or OFF (1: alarm ON, 0: alarm OFF)
        parameter = 0;
      lcd.setCursor(x, y);
      if(i == 7){                                           // For alarms ON & OFF
        if(parameter == 1)  lcd.print("ON ");
        else                lcd.print("OFF");
      }
      else{
        sprintf(text,"%02u", parameter);
        lcd.print(text);
      }
      if(i >= 5){
        DS3231_read();                          // Read data from DS3231
        DS3231_display();                       // Display DS3231 time and calendar
      }
      delay(200);                               // Wait 200ms
    }
    lcd.setCursor(x, y);
    lcd.print("  ");                            // Print two spaces
    if(i == 7) lcd.print(" ");                  // Print space (for alarms ON & OFF)
    Blink();                                    // Call Blink function
    lcd.setCursor(x, y);
    if(i == 7){                                 // For alarms ON & OFF
      if(parameter == 1)  lcd.print("ON ");
      else                lcd.print("OFF");
    }
    else{
      sprintf(text,"%02u", parameter);
      lcd.print(text);
    }
    Blink();
    if(i >= 5){
      DS3231_read();
      DS3231_display();}
    if((!digitalRead(button1) && i < 5) || (!digitalRead(button3) && i >= 5)){
      i++;                                      // Increment 'i' for the next parameter
      return parameter;                         // Return parameter value and exit
    }
  }
}
 
void loop() {
  if(!digitalRead(button1)){                    // If B1 button is pressed
      i = 0;
      hour   = edit(0, 0, hour);
      minute = edit(3, 0, minute);
      while(!digitalRead(button1));             // Wait until button B1 released
      while(true){
        while(!digitalRead(button2)){           // If button B2 button is pressed
          day++;                                // Increment day
          if(day > 7) day = 1;
          calendar_display();                   // Call display_calendar function
          lcd.setCursor(0, 1);
          lcd.print(calendar);                  // Display calendar
          delay(200);
        }
        lcd.setCursor(0, 1);
        lcd.print("   ");                       // Print 3 spaces
        Blink();
        lcd.setCursor(0, 1);
        lcd.print(calendar);                    // Print calendar
        Blink();                                // Call Blink function
        if(!digitalRead(button1))               // If button B1 is pressed
          break;
      }
      date = edit(4, 1, date);                  // Edit date
      month = edit(7, 1, month);                // Edit month
      year = edit(12, 1, year);                 // Edit year
      // Convert decimal to BCD
      minute = ((minute / 10) << 4) + (minute % 10);
      hour = ((hour / 10) << 4) + (hour % 10);
      date = ((date / 10) << 4) + (date % 10);
      month = ((month / 10) << 4) + (month % 10);
      year = ((year / 10) << 4) + (year % 10);
      // End conversion
      // Write time & calendar data to DS3231 RTC
      Wire.beginTransmission(0x68);             // Start I2C protocol with DS3231 address
      Wire.write(0);                            // Send register address
      Wire.write(0);                            // Reset sesonds and start oscillator
      Wire.write(minute);                       // Write minute
      Wire.write(hour);                         // Write hour
      Wire.write(day);                          // Write day
      Wire.write(date);                         // Write date
      Wire.write(month);                        // Write month
      Wire.write(year);                         // Write year
      Wire.endTransmission();                   // Stop transmission and release the I2C bus
      delay(200);
    }
    if(!digitalRead(button3)){                  // If B3 button is pressed
      while(!digitalRead(button3));             // Wait until button B3 released
      i = 5;
      alarm1_hour   = edit(4,  2, alarm1_hour);
      alarm1_minute = edit(7,  2, alarm1_minute);
      alarm1_status = edit(17, 2, alarm1_status);
      i = 5;
      alarm2_hour   = edit(4,  3, alarm2_hour);
      alarm2_minute = edit(7,  3, alarm2_minute);
      alarm2_status = edit(17, 3, alarm2_status);
      alarm1_minute = ((alarm1_minute / 10) << 4) + (alarm1_minute % 10);
      alarm1_hour   = ((alarm1_hour   / 10) << 4) + (alarm1_hour % 10);
      alarm2_minute = ((alarm2_minute / 10) << 4) + (alarm2_minute % 10);
      alarm2_hour   = ((alarm2_hour   / 10) << 4) + (alarm2_hour % 10);
      // Write alarms data to DS3231
      Wire.beginTransmission(0x68);               // Start I2C protocol with DS3231 address
      Wire.write(7);                              // Send register address (alarm1 seconds)
      Wire.write(0);                              // Write 0 to alarm1 seconds
      Wire.write(alarm1_minute);                  // Write alarm1 minutes value to DS3231
      Wire.write(alarm1_hour);                    // Write alarm1 hours value to DS3231
      Wire.write(0x80);                           // Alarm1 when hours, minutes, and seconds match
      Wire.write(alarm2_minute);                  // Write alarm2 minutes value to DS3231
      Wire.write(alarm2_hour);                    // Write alarm2 hours value to DS3231
      Wire.write(0x80);                           // Alarm2 when hours and minutes match
      Wire.write(4 | alarm1_status | (alarm2_status << 1));      // Write data to DS3231 control register (enable interrupt when alarm)
      Wire.write(0);                              // Clear alarm flag bits
      Wire.endTransmission();                     // Stop transmission and release the I2C bus
      delay(200);                                 // Wait 200ms
    }
    if(!digitalRead(button2) && digitalRead(alarm_pin)){         // When button B2 pressed with alarm (Reset and turn OFF the alarm)
      digitalWrite(alarm_pin, LOW);               // Turn OFF the alarm indicator
      Wire.beginTransmission(0x68);               // Start I2C protocol with DS3231 address
      Wire.write(0x0E);                           // Send register address (control register)
      // Write data to control register (Turn OFF the occurred alarm and keep the other as it is)
      Wire.write(4 | (!bitRead(status_reg, 0) & alarm1_status) | ((!bitRead(status_reg, 1) & alarm2_status) << 1));
      Wire.write(0);                              // Clear alarm flag bits
      Wire.endTransmission();                     // Stop transmission and release the I2C bus
    }
    DS3231_read();                                // Read time and calendar parameters from DS3231 RTC
    alarms_read_display();                        // Read and display alarms parameters
    DS3231_display();                             // Display time & calendar
    delay(50);                                    // Wait 50ms
}
// End of code

 

بیشتر بخوانید...  خانه هوشمند با بلوتوث

 

دیدگاه‌ها (6)

*
*

    محمد مهمان اسفند 22, 1398 پاسخ

    ببخشید من ساعت را درست کردم و تنظیم هم کردم فقط بعد از اینکه تنظیم کردم نمیدانم چگونه باید تنظیمات را ذخیره کنم راهنمایی کنید

      Admin مدیر کل آبان 14, 1399 پاسخ

      سلام
      دقت کنید که ماژولی که میخرید روش باتری داشته باشه اگه بدون باتری خریدید خودتون واسش باتری بخرید و بذارید روش چون همون باتری به مدار ساعت برق میرسونه و زمان رو با گذر زمان میبره جلو

    محمد مهمان اسفند 22, 1398 پاسخ

    ببخشید من ساعت را درست و تنظیم کردم و بعد ولتاژ را قطع کردم و بعد دوباره وصل کردم و دوباره باید از اول ساعت را تنظیم میکردم چگونه باید تنظیمات را که انجام میدهیم ذخیره کنیم لطفا راهنمایی کنید

      Admin مدیر کل آبان 14, 1399 پاسخ

      سلام
      حتما ماژولتون روش باتری نداشته

    مهسا مهمان آذر 26, 1399 پاسخ

    سلام. میشه بیشتر از دو تا آلارم تعریف کرد؟

      Admin مدیر کل دی 21, 1399 پاسخ

      سلام
      بله میشه...